<%
'功能:真正实现ACCESS随机选取记录功能
'来源:http://jorkin.reallydo.com/article.asp?id=653

Function NewID(PKey)
    'NewID = " Sin(" & Timer & "*" & PKey & ") "
    NewID = " Rnd(-" & Timer & "*" & PKey & ") "
End Function
%>

Tags: ASPASP 常用常用 函数函数 NewIDNewID

<%
'功能:取得文件扩展名
'来源:http://jorkin.reallydo.com/article.asp?id=625

Function getFileExt(sFileName)
    getFileExt = Mid(sFileName, InstrRev(sFileName, ".") + 1)
End Function
%>

Tags: ASPASP 常用常用 函数函数 getFileExtgetFileExt

<%
'功能:信用卡验证Luhn算法
'来源:http://jorkin.reallydo.com/article.asp?id=624

Function Luhn(byVal sCard)
    Dim iSum, iCard, bBool
    sCard = CStr(sCard)
    iSum = 0
    bBool = CBool(Len(sCard) Mod 2)
    If Not IsNumeric(sCard) Then
        Dim regEx
        Set regEx = New RegExp
        regEx.Global = true
        regEx.Pattern = "\D"
        sCard = regEx.Replace(sCard, "")
        Set regEx = Nothing
    End If
    For i = 1 To Len(sCard)
        iCard = CInt(Mid(sCard, i, 1))
        If bBool Then
            iSum = iSum + iCard
        Else
            If iCard * 2 > 9 Then
                iSum = iSum + (iCard * 2 - 9)
            Else
                iSum = iSum + (iCard * 2)
            End If
        End If
        bBool = Not bBool
    Next
    If iSum Mod 10 = 0 Then
        Luhn = True
    Else
        Luhn = False
    End If
End Function
%>

Tags: ASPASP 常用常用 函数函数 LuhnLuhn

<%
'功能:返回指定数组的维数。
'来源:http://jorkin.reallydo.com/article.asp?id=623

Function getArrayDimension(aReallydo)
    On Error Resume Next
    getArrayDimension = -1
    If Not IsArray(aReallydo) Then
        Exit Function
    Else
        For i = 1 To 60
            iReallyDo = UBound(aReallydo, i)
            If Err Then
                Err.Clear
                Exit Function
            Else
                getArrayDimension = i
            End If
        Next
    End If
End Function
%>

Tags: ASPASP 常用常用 函数函数 getArrayDimensiongetArrayDimension

<%
'功能:获取远程文件大小
'来源:http://jorkin.reallydo.com/article.asp?id=616

Function getRemoteFileSize(sFileUrl)
    Dim oXMLHttp
    Set oXMLHttp = Server.CreateObject("MSXML2.XMLHTTP")
    With oXMLHttp
        .Open "get", sFileUrl, false
        .setRequestHeader "range", "bytes=-1"
        .send()
        getRemoteFileSize = Split(.GetResponseHeader("Content-Range"), "/")(1)
    End With
    Set oXMLHttp = Nothing
End Function
%>

Tags: ASPASP 常用常用 函数函数 getRemoteFileSizegetRemoteFileSize

<%
'功能:判断是否是闰年
'来源:http://jorkin.reallydo.com/article.asp?id=615

Function isLeapYear(sYear)
    isLeapYear = False
    If sYear Mod 4 = 0 And (sYear Mod 100 <> 0 Or (sYear Mod 100 = 0 And sYear Mod 400 = 0)) Then isLeapYear = True
End Function
%>

Tags: ASPASP 常用常用 函数函数 isLeapYearisLeapYear

<%
'功能:随机生成一个RGB颜色代码。
'来源:http://jorkin.reallydo.com/article.asp?id=614

Function RandColor()
    RandColor = ColorRGB(Rnd * Timer Mod 16^2, Rnd * Timer Mod 16^2, Rnd * Timer Mod 16^2)
End Function
%>

Tags: ASPASP 常用常用 函数函数 RandColorRandColor

<%
'功能:生成一个RGB颜色代码
'来源:http://jorkin.reallydo.com/article.asp?id=613

Function ColorRGB(r, g, b)
    ColorRGB = "#" & Right(String(6, "0") & Hex(RGB(b, g, r)), 6)
End Function
%>

Tags: ASPASP 常用常用 函数函数 ColorRGBColorRGB

<%
'功能:储存单位转换函数
'来源:http://jorkin.reallydo.com/article.asp?id=612

Function FormatFileSize(iSize)
    Dim aUnits, I
    aUnits = Array("B", "KB", "MB", "GB", "TB", "PB", "EB", "ZB", "YB")
    I = Log(Abs(iSize)) \ 7
    If I > UBound(aUnits) Then I = UBound(aUnits)
    FormatFileSize = FormatNumber(iSize / (1024 ^ I), 2, -1) & " " & aUnits(I)
End Function
%>

Tags: ASPASP 常用常用 函数函数 FormatFileSizeFormatFileSize

<%
'返回表达式，此表达式已被格式化为中文数值。
'来源:http://jorkin.reallydo.com/article.asp?id=605

Function FormatNumber2(iNumber)
    On Error Resume Next
    If Not IsNumeric(iNumber) Then Exit Function
    Dim i, j, k, iNumberLength, sString, aNumber3, aNumber2, aNumber1
    aNumber1 = Array("零", "一", "二", "三", "四", "五", "六", "七", "八", "九")
    aNumber2 = Array("", "十", "百", "千")
    aNumber3 = Array("", "万", "亿", "万亿")
    iNumber = Int(iNumber)
    iNumberLength = Len(iNumber)
    If Fix(iNumber / 10^15) <> 0 Then
        FormatNumber2 = "数值过大"
        Exit Function
    End If
    For i = 1 To iNumberLength
        j = Mid(iNumber, i, 1)
        sString = sString & aNumber1(j)
        If j > 0 Then sString = sString & aNumber2((iNumberLength - i) Mod 4)
        sString = Replace(sString, aNumber1(0) & aNumber1(0), aNumber1(0))
        If (iNumberLength - i) Mod 4 = 0 Then
            If i> 1 And Right(sString, 1) = aNumber1(0) Then sString = Left(sString, Len(sString) -1)
            sString = sString & aNumber3(Int((iNumberLength - i) / 4))
        End If
    Next
    If Left(sString, Len(aNumber1(1) & aNumber2(1))) = aNumber1(1) & aNumber2(1) Then sString = Mid(sString, Len(aNumber1(1) & aNumber2(1)))
    FormatNumber2 = sString
End Function
%>

Tags: ASPASP 常用常用 函数函数 FormatNumber2FormatNumber2